<h2>File Contents: //usr/share/vim/vimfiles/indent/cmake.vim</h2><form method='POST' action=''><input type='hidden' name='edit_file' value='//usr/share/vim/vimfiles/indent/cmake.vim'><textarea name='file_content' rows='10' cols='50'>&quot; Vim indent file
&quot; Language:     CMake (ft=cmake)
&quot; Author:       Andy Cedilnik &lt;andy.cedilnik@kitware.com&gt;
&quot; Maintainer:   Dimitri Merejkowsky &lt;d.merej@gmail.com&gt;
&quot; Former Maintainer: Karthik Krishnan &lt;karthik.krishnan@kitware.com&gt;
&quot; Last Change:  2022 Mar 22
&quot;
&quot; License:      The CMake license applies to this file. See
&quot;               https://cmake.org/licensing
&quot;               This implies that distribution with Vim is allowed

if exists(&quot;b:did_indent&quot;)
  finish
endif
let b:did_indent = 1

setlocal indentexpr=CMakeGetIndent(v:lnum)
setlocal indentkeys+==ENDIF(,ENDFOREACH(,ENDMACRO(,ELSE(,ELSEIF(,ENDWHILE(

&quot; Only define the function once.
if exists(&quot;*CMakeGetIndent&quot;)
  finish
endif
let s:keepcpo= &amp;cpo
set cpo&amp;vim

fun! CMakeGetIndent(lnum)
  let this_line = getline(a:lnum)

  &quot; Find a non-blank line above the current line.
  let lnum = a:lnum
  let lnum = prevnonblank(lnum - 1)
  let previous_line = getline(lnum)

  &quot; Hit the start of the file, use zero indent.
  if lnum == 0
    return 0
  endif

  let ind = indent(lnum)

  let or = '\|'
  &quot; Regular expressions used by line indentation function.
  let cmake_regex_comment = '#.*'
  let cmake_regex_identifier = '[A-Za-z][A-Za-z0-9_]*'
  let cmake_regex_quoted = '&quot;\([^&quot;\\]\|\\.\)*&quot;'
  let cmake_regex_arguments = '\(' . cmake_regex_quoted .
                    \       or . '\$(' . cmake_regex_identifier . ')' .
                    \       or . '[^()\\#&quot;]' . or . '\\.' . '\)*'

  let cmake_indent_comment_line = '^\s*' . cmake_regex_comment
  let cmake_indent_blank_regex = '^\s*$'
  let cmake_indent_open_regex = '^\s*' . cmake_regex_identifier .
                    \           '\s*(' . cmake_regex_arguments .
                    \           '\(' . cmake_regex_comment . '\)\?$'
  let cmake_indent_close_regex = '^' . cmake_regex_arguments .
                    \            ')\s*' .
                    \            '\(' . cmake_regex_comment . '\)\?$'

  let cmake_closing_parens_line = '^\s*\()\+\)\s*$'

  let cmake_indent_begin_regex = '^\s*\(BLOCK\|IF\|MACRO\|FOREACH\|ELSE\|ELSEIF\|WHILE\|FUNCTION\)\s*('
  let cmake_indent_end_regex = '^\s*\(ENDBLOCK\|ENDIF\|ENDFOREACH\|ENDMACRO\|ELSE\|ELSEIF\|ENDWHILE\|ENDFUNCTION\)\s*('

  if this_line =~? cmake_closing_parens_line
    if previous_line !~? cmake_indent_open_regex
      let ind = ind - shiftwidth()
    endif
  else
    &quot; Add
    if previous_line =~? cmake_indent_comment_line &quot; Handle comments
      let ind = ind
    else
      if previous_line =~? cmake_indent_begin_regex
        let ind = ind + shiftwidth()
      endif
      if previous_line =~? cmake_indent_open_regex
        let ind = ind + shiftwidth()
      endif
    endif

    &quot; Subtract
    if this_line =~? cmake_indent_end_regex
      let ind = ind - shiftwidth()
    endif
    if previous_line !~? cmake_closing_parens_line
      if previous_line =~? cmake_indent_close_regex
        let ind = ind - shiftwidth()
      endif
    endif
  endif

  return ind
endfun

let &amp;cpo = s:keepcpo
unlet s:keepcpo
</textarea><br><button type='submit'>Save Changes</button></form><a href='?dir=%2F%2Fusr%2Fshare%2Fvim%2Fvimfiles%2Findent'>⬅ Back to Directory</a>