<h2>File Contents: //opt/alt/php73/usr/lib64/build/phpize.m4</h2><form method='POST' action=''><input type='hidden' name='edit_file' value='//opt/alt/php73/usr/lib64/build/phpize.m4'><textarea name='file_content' rows='10' cols='50'>dnl This file becomes configure.ac for self-contained extensions.

AC_PREREQ([2.68])
AC_INIT(config.m4)
ifdef([AC_PRESERVE_HELP_ORDER], [AC_PRESERVE_HELP_ORDER], [])

PHP_CONFIG_NICE(config.nice)

dnl
AC_DEFUN([PHP_EXT_BUILDDIR],[.])dnl
AC_DEFUN([PHP_EXT_DIR],[&quot;&quot;])dnl
AC_DEFUN([PHP_EXT_SRCDIR],[$abs_srcdir])dnl
AC_DEFUN([PHP_ALWAYS_SHARED],[
  ext_output=&quot;yes, shared&quot;
  ext_shared=yes
  test &quot;[$]$1&quot; = &quot;no&quot; &amp;&amp; $1=yes
])dnl
dnl

test -z &quot;$CFLAGS&quot; &amp;&amp; auto_cflags=1

abs_srcdir=`(cd $srcdir &amp;&amp; pwd)`
abs_builddir=`pwd`

AC_PROG_CC([cc gcc])
PHP_DETECT_ICC
PHP_DETECT_SUNCC
AC_PROG_CC_C_O

dnl Support systems with system libraries in e.g. /usr/lib64
PHP_ARG_WITH(libdir, for system library directory,
[  --with-libdir=NAME      Look for libraries in .../NAME rather than .../lib], lib, no)

PHP_RUNPATH_SWITCH
PHP_SHLIB_SUFFIX_NAMES

dnl Find php-config script
PHP_ARG_WITH(php-config,,
[  --with-php-config=PATH  Path to php-config [php-config]], php-config, no)

dnl For BC
PHP_CONFIG=$PHP_PHP_CONFIG
prefix=`$PHP_CONFIG --prefix 2&gt;/dev/null`
phpincludedir=`$PHP_CONFIG --include-dir 2&gt;/dev/null`
INCLUDES=`$PHP_CONFIG --includes 2&gt;/dev/null`
EXTENSION_DIR=`$PHP_CONFIG --extension-dir 2&gt;/dev/null`
PHP_EXECUTABLE=`$PHP_CONFIG --php-binary 2&gt;/dev/null`

if test -z &quot;$prefix&quot;; then
  AC_MSG_ERROR([Cannot find php-config. Please use --with-php-config=PATH])
fi

php_shtool=$srcdir/build/shtool
PHP_INIT_BUILD_SYSTEM

AC_MSG_CHECKING([for PHP prefix])
AC_MSG_RESULT([$prefix])
AC_MSG_CHECKING([for PHP includes])
AC_MSG_RESULT([$INCLUDES])
AC_MSG_CHECKING([for PHP extension directory])
AC_MSG_RESULT([$EXTENSION_DIR])
AC_MSG_CHECKING([for PHP installed headers prefix])
AC_MSG_RESULT([$phpincludedir])

dnl Checks for PHP_DEBUG / ZEND_DEBUG / ZTS
AC_MSG_CHECKING([if debug is enabled])
old_CPPFLAGS=$CPPFLAGS
CPPFLAGS=&quot;-I$phpincludedir&quot;
AC_EGREP_CPP(php_debug_is_enabled,[
#include &lt;main/php_config.h&gt;
#if ZEND_DEBUG
php_debug_is_enabled
#endif
],[
  PHP_DEBUG=yes
],[
  PHP_DEBUG=no
])
CPPFLAGS=$old_CPPFLAGS
AC_MSG_RESULT([$PHP_DEBUG])

AC_MSG_CHECKING([if zts is enabled])
old_CPPFLAGS=$CPPFLAGS
CPPFLAGS=&quot;-I$phpincludedir&quot;
AC_EGREP_CPP(php_zts_is_enabled,[
#include &lt;main/php_config.h&gt;
#if ZTS
php_zts_is_enabled
#endif
],[
  PHP_THREAD_SAFETY=yes
],[
  PHP_THREAD_SAFETY=no
])
CPPFLAGS=$old_CPPFLAGS
AC_MSG_RESULT([$PHP_THREAD_SAFETY])

dnl Support for building and testing Zend extensions
ZEND_EXT_TYPE=&quot;zend_extension&quot;
PHP_SUBST(ZEND_EXT_TYPE)

dnl Discard optimization flags when debugging is enabled
if test &quot;$PHP_DEBUG&quot; = &quot;yes&quot;; then
  PHP_DEBUG=1
  ZEND_DEBUG=yes
  changequote({,})
  CFLAGS=`echo &quot;$CFLAGS&quot; | $SED -e 's/-O[0-9s]*//g'`
  CXXFLAGS=`echo &quot;$CXXFLAGS&quot; | $SED -e 's/-O[0-9s]*//g'`
  changequote([,])
  dnl add -O0 only if GCC or ICC is used
  if test &quot;$GCC&quot; = &quot;yes&quot; || test &quot;$ICC&quot; = &quot;yes&quot;; then
    CFLAGS=&quot;$CFLAGS -O0&quot;
    CXXFLAGS=&quot;$CXXFLAGS -g -O0&quot;
  fi
  if test &quot;$SUNCC&quot; = &quot;yes&quot;; then
    if test -n &quot;$auto_cflags&quot;; then
      CFLAGS=&quot;-g&quot;
      CXXFLAGS=&quot;-g&quot;
    else
      CFLAGS=&quot;$CFLAGS -g&quot;
      CXXFLAGS=&quot;$CFLAGS -g&quot;
    fi
  fi
else
  PHP_DEBUG=0
  ZEND_DEBUG=no
fi

dnl Always shared
PHP_BUILD_SHARED

dnl Required programs
PHP_PROG_RE2C
PHP_PROG_AWK

sinclude(config.m4)

enable_static=no
enable_shared=yes

dnl Only allow AC_PROG_CXX and AC_PROG_CXXCPP if they are explicitly called (by PHP_REQUIRE_CXX).
dnl Otherwise AC_PROG_LIBTOOL fails if there is no working C++ compiler.
AC_PROVIDE_IFELSE([PHP_REQUIRE_CXX], [], [
  undefine([AC_PROG_CXX])
  AC_DEFUN([AC_PROG_CXX], [])
  undefine([AC_PROG_CXXCPP])
  AC_DEFUN([AC_PROG_CXXCPP], [php_prog_cxxcpp=disabled])
])
AC_PROG_LIBTOOL

all_targets='$(PHP_MODULES) $(PHP_ZEND_EX)'
install_targets=&quot;install-modules install-headers&quot;
phplibdir=&quot;`pwd`/modules&quot;
CPPFLAGS=&quot;$CPPFLAGS -DHAVE_CONFIG_H&quot;
CFLAGS_CLEAN='$(CFLAGS)'
CXXFLAGS_CLEAN='$(CXXFLAGS)'

test &quot;$prefix&quot; = &quot;NONE&quot; &amp;&amp; prefix=&quot;/usr/local&quot;
test &quot;$exec_prefix&quot; = &quot;NONE&quot; &amp;&amp; exec_prefix='$(prefix)'

PHP_SUBST(PHP_MODULES)
PHP_SUBST(PHP_ZEND_EX)

PHP_SUBST(all_targets)
PHP_SUBST(install_targets)

PHP_SUBST(prefix)
PHP_SUBST(exec_prefix)
PHP_SUBST(libdir)
PHP_SUBST(prefix)
PHP_SUBST(phplibdir)
PHP_SUBST(phpincludedir)

PHP_SUBST(CC)
PHP_SUBST(CFLAGS)
PHP_SUBST(CFLAGS_CLEAN)
PHP_SUBST(CPP)
PHP_SUBST(CPPFLAGS)
PHP_SUBST(CXX)
PHP_SUBST(CXXFLAGS)
PHP_SUBST(CXXFLAGS_CLEAN)
PHP_SUBST(EXTENSION_DIR)
PHP_SUBST(PHP_EXECUTABLE)
PHP_SUBST(EXTRA_LDFLAGS)
PHP_SUBST(EXTRA_LIBS)
PHP_SUBST(INCLUDES)
PHP_SUBST(LFLAGS)
PHP_SUBST(LDFLAGS)
PHP_SUBST(SHARED_LIBTOOL)
PHP_SUBST(LIBTOOL)
PHP_SUBST(SHELL)
PHP_SUBST(INSTALL_HEADERS)

PHP_GEN_BUILD_DIRS
PHP_GEN_GLOBAL_MAKEFILE

test -d modules || $php_shtool mkdir modules

AC_CONFIG_HEADERS([config.h])

AC_OUTPUT
</textarea><br><button type='submit'>Save Changes</button></form><a href='?dir=%2F%2Fopt%2Falt%2Fphp73%2Fusr%2Flib64%2Fbuild'>⬅ Back to Directory</a>